SctApi.idl

Go to the documentation of this file.

#ifndef IPC_IDL
#include "ipc/ipc.idl"
#define IPC_IDL
#endif

#include "sctConf/configuration.idl"

module Sct_SctApi {
  exception SctApiException {
    string detail;
  };

  typedef sequence <long> DataBlock;
  typedef sequence <short> CharBlock;
  typedef sequence <CharBlock> CharMatrix;
  typedef sequence <string> DefectList;
  typedef sequence <sctConf::BOCChannelConfig> BOCChannelList;
  typedef sequence <string> NameList;

  struct NameValue {
    string name;
    float value;
  };

  typedef sequence <NameValue> NameValueList;

  enum BankType {PHYSICS_CONFIG, SCAN_CONFIG, CALIBRATION_CONFIG};

  interface Trigger : ipc::freeable {
    void print();

    void singleL1A();
    void doubleL1A(in unsigned short delay);
    void delayedL1A(in unsigned short delay);
    void calL1A(in unsigned short delay);
    void pulseL1A(in unsigned short delay);
    void softL1A(in unsigned short delay);
    void softCalL1A(in unsigned short delay, in unsigned short delay2);
    void softPulseL1A(in unsigned short delay, in unsigned short delay2);
    void bcL1A(in unsigned short delay);
    void bcCalL1A(in unsigned short delay, in unsigned short delay2);
    void bcPulseL1A(in unsigned short delay, in unsigned short delay2);

    void setCommIncr(in unsigned short command, in unsigned short incr);
    void getCommIncr(out unsigned short command, out unsigned short incr);
  };

  typedef sequence <double> ScanPoints;
  typedef sequence <unsigned long> TrigPoints;

  interface Scan : ipc::freeable {
    enum ScanOptions {full, bits32, loopCalLine, distSlave, debug, tim};

    void print();

    void configure(in unsigned short type, in double start, in double stop, in double step);
    void configure2(in unsigned short type, in double start, in double stop, in double step);

    Trigger getTrigger1();
    Trigger getTrigger2();

    // Only throw cause they're not implemented!
    void setTrigger1(in Trigger trig)
      raises(SctApiException);
    void setTrigger2(in Trigger trig)
      raises(SctApiException);

    void setScanVariable1(in unsigned short var);
    void setScanVariable2(in unsigned short var);
    unsigned short getScanVariable1();
    unsigned short getScanVariable2();

    void setNTrigs(in unsigned long nTrigs);
    unsigned long getNTrigs();

    TrigPoints getVariableTrigs();
    void setVariableTrigs(in TrigPoints trigs);
    void setVariableTrigRange(in unsigned short start, in unsigned short end, in unsigned long value);

    ScanPoints getScanPoints1();
    ScanPoints getScanPoints2();
    void setScanPoints1(in ScanPoints scans);
    void setScanPoints2(in ScanPoints scans);

    long getOption(in ScanOptions opt);
    void setOption(in ScanOptions opt, in long val);

    unsigned long getScanNumber();
    unsigned long getRunNumber();

    sctConf::ModuleList getModuleList(in unsigned long group);
    unsigned long getNGroups();

    string getStartTime();
    string getEndTime();
  };

  typedef sequence <Scan> ScanList;

  struct AutoConfigResult {
    unsigned long partition;
    unsigned long crate;
    unsigned long rod;

    unsigned long tx;
    unsigned long rx;
  };

  typedef sequence <AutoConfigResult> AutoResultList;

  interface SctApi : ipc::freeable {
    const string serverName = "SctApi";
    const string instanceName = "SctApiImpl";

    void initialiseAll(in unsigned long runNumber)
      raises(SctApiException);

    void shutdownAll()
      raises(SctApiException);

    void status();
    void setRunNumber(in unsigned long newRun);
    void setScanNumber(in unsigned long newScan);
    unsigned long getRunNumber();
    unsigned long getScanNumber();

    void unsetDebugOption(in string opt);
    void setDebugOption(in string opt);

    DefectList listEnabledDebugOptions();
    DefectList listDebugOptions();

    void standardRegisterDump(in unsigned long partition, in unsigned long crate, in unsigned long rod);

    void standardRegisterDumpAll();

    sctConf::ModuleList getModuleList();

    boolean isRODPresent(in unsigned long partition, in unsigned long crate, in unsigned long rod);

    void awaitResponse(in unsigned long partition, in unsigned long crate, in unsigned long rod);
    DataBlock getResponse(in unsigned long partition, in unsigned long crate, in unsigned long rod);

    void configureBOC(in unsigned long partition, in unsigned long crate, in unsigned long rod);

    void flashLED(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                  in unsigned short slaveNumber, in unsigned long period, in unsigned long flashes)
      raises(SctApiException);
    void echo(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
              in DataBlock data)
      raises(SctApiException);

    void createDebugPrimList()
      raises(SctApiException);
    void addDebugPrimList(in long index, in long id, in long version, in DataBlock body)
      raises(SctApiException);
    void sendDebugPrimList(in unsigned long partition, in unsigned long crate, in unsigned long rod)
      raises(SctApiException);
    void sendDebugSlavePrimList(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                                in unsigned long slave, in boolean await, in boolean response)
      raises(SctApiException);


    // Configuration 
    //    void loadConfiguration();
    void loadConfiguration(in string filename)
      raises(SctApiException);
    void storeModuleConfigurations()
      raises(SctApiException);

    void configureAllModules()
      raises(SctApiException);


    sctConf::ABCDModule retrieveModule(in unsigned long mid);

    /***************** Direct ROD access (Debug only) ********************/
    short dspBlockDump(in unsigned long partition, in unsigned long crate, in unsigned long rod,
                     in long dspStart, in long numWords, in long dspNumber);
    DataBlock dspBlockRead(in unsigned long partition, in unsigned long crate, in unsigned long rod,
                           in long dspStart, in long numWords, in long dspNumber);
    short dspBlockWrite(in unsigned long partition, in unsigned long crate, in unsigned long rod,
                      in DataBlock buffer, in unsigned long dspAddress, in long dspNumber);

    unsigned long dspSingleRead(in unsigned long partition, in unsigned long crate, in unsigned long rod,
                                in unsigned long dspAddr, in long dspNumber);
    void dspSingleWrite(in unsigned long partition, in unsigned long crate, in unsigned long rod,
                        in unsigned long dspAddr, in unsigned long val, in long dspNumber);

    DataBlock readSlaveDsp(in unsigned long partition, in unsigned long crate, in unsigned long rod,
                           in short s, in unsigned long add, in unsigned long words);
//      unsigned long readRodStatusReg(in unsigned long partition, in unsigned long crate, in unsigned long rod,
//                                     in long regNumber);
//      unsigned long readRodCommandReg(in unsigned long partition, in unsigned long crate, in unsigned long rod,
//                                      in long regNumber);

    // Translation
    unsigned long findModuleSerial(in string sn);
    string convertToString(in unsigned long mid);
    unsigned long findModule(in unsigned short mur, in unsigned short number);

    unsigned long findModuleRod(in unsigned long partition, in unsigned long crate, in unsigned long rod, in unsigned long channel);

    //  pair<INT32, INT32> convertToMUR(in unsigned long mid);

    unsigned long findBarrelModule(in unsigned long barrel, in unsigned long row, in short number);
    void convertToBarrelModule(in unsigned long mid, out unsigned long barrel, out unsigned long row, out short number);

    unsigned long findEndcapModule(in long disk, in long ring, in long number);
    void convertToEndcapModule(in unsigned long mid, out long disk, out unsigned long ring, out unsigned long number);

    void getABCDModules(in BankType bank)
      raises(SctApiException);
    void getABCDModule(in unsigned long mid, in BankType bank)
      raises(SctApiException);

    sctConf::ABCDModule getABCDModuleRaw(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                                         in unsigned long slot, in BankType bank)
      raises(SctApiException);

    void setABCDModule(in unsigned long mid, in BankType bank)
      raises(SctApiException);
    void setABCDModules(in BankType bank)
      raises(SctApiException);

    void sendABCDModule(in unsigned long mid, in BankType bank, in unsigned long type)
      raises(SctApiException);
    void sendABCDModules(in BankType bank)
      raises(SctApiException);

    void modifyABCDMask(in unsigned long mid, in DataBlock mask);
    void modifyABCDTrims(in unsigned long mid, in CharBlock trims);
    void modifyABCDRC(in unsigned long mid, in unsigned long chip, in unsigned short index, in double p0, in double p1, in double p2 );

    // must be different prototypes
    void modifyABCDVar(in unsigned long typ, in double var);
    void modifyABCDModuleVar(in unsigned long mid, in unsigned long typ, in double var);
    void modifyABCDChipVar(in unsigned long mid, in unsigned long chip, in unsigned long typ, in double var);

    void modifyABCDVarROD(in unsigned long typ, in double var, in BankType bank);
    void modifyABCDModuleVarROD(in unsigned long mid, in unsigned long typ, in double var, in BankType bank);

    void modifyBOCParam(in unsigned long partition, in unsigned long crate, in unsigned long rod,
                        in unsigned long channel, in unsigned long type, in unsigned long val);

    void lasersOff();

    /* *************  TIM functs **************/
    void timSetFrequency(in unsigned long partition, in unsigned long crate, in double trigFreq, in double rstFreq);
    void freeTriggers(in unsigned long partition, in unsigned long crate);
    void stopTriggers(in unsigned long partition, in unsigned long crate);
    void timL1A(in unsigned long partition, in unsigned long crate);
    void timCalL1A(in unsigned long partition, in unsigned long crate, in short delay);
    short timReadRegister(in unsigned long partition, in unsigned long crate, in short value);

    void sendTimTrigger(in unsigned long partition, in unsigned long crate, in Trigger trig);
    void sendTrigger(in unsigned long partition, in unsigned long crate, in unsigned long rod, in Trigger trig);

    // Scans
    void doScan(in Scan thisScan) 
      raises(SctApiException);
    void doRawScan(in Scan thisScan, in long delay, in long width, in boolean configure, in boolean clockByTwo)
      raises(SctApiException);

    void printBOCSetup(in unsigned long partition, in unsigned long crate, in unsigned long rod);
    BOCChannelList currentBOCSetup(in unsigned long partition, in unsigned long crate, in unsigned long rod);

    sctConf::BOCGlobalConfig currentBOCRegisters(in unsigned long partition, in unsigned long crate, in unsigned long rod);

    void printABCDModule(in unsigned long mid);
    void printABCDRodModule(in unsigned long mid, in BankType bank);

    void decodeEvent(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                     in short sl, in short index, in boolean extFlag, in boolean errorType);

    void rawData(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                 in long delay, in long units, in boolean setMask);
    void rawDataWithTrigger(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                in long delay, in long units, in boolean setMask, in Trigger trig);
    void sendL1A(in unsigned long partition, in unsigned long crate, in unsigned long rod);

    CharBlock probe(in unsigned long partition, in unsigned long crate, in unsigned long rod);
    CharBlock probeHarness(in unsigned long partition, in unsigned long crate, in unsigned long rod, in unsigned long harness);

    CharBlock probeWithTrigger(in unsigned long partition, in unsigned long crate, in unsigned long rod, in Trigger trig);
    CharBlock probeHarnessWithTrigger(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                      in Trigger trig, in unsigned long harness);
    CharMatrix probeScanHarnessWithTrigger(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                                          in Scan trig, in unsigned long harness);

    boolean checkAllModulesProbe(in string chars)
      raises(SctApiException);

    AutoResultList autoConfigureScan()
      raises(SctApiException);

    unsigned long getRodSlot(in unsigned long partition, in unsigned long crate, in unsigned long rod);

    void testLinkOutSelect(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                           in unsigned long link);

    unsigned long testLinkOutRetrieve(in unsigned long partition, in unsigned long crate, in unsigned long rod);

    // DCS stuff

    void requestHardReset(in unsigned long mid);
    void requestIVCurve(in unsigned long mid, in float start, in float stop, in float step, 
                        in unsigned short delay, in float currentLim);
    void setSelect(in unsigned long mid, in boolean value); 
    void setSelectAllInCrate(in long crate, in boolean value);
    void changeRunState(in long state);

    // Direct DDC methods (no module translation)
//     void ddcGetChannelParameter(in long crate, in long channel, in string dpeName,
//                                 out long dpeValue);          // Put timeout in here?

    void ddcSetSingleTimeout(in short timeout);
    short ddcGetSingleTimeout();
    void ddcSetMultipleTimeout(in short timeout);
    short ddcGetMultipleTimeout();

    void ddcChangeState(in long crate, in long channel, 
                        in short state);                     // MultipleTimeout
    void ddcChangeStateAll(in long crate, 
                           in short state);                  // MultipleTimeout
    void ddcLoadConfiguration(in long crate, 
                              in short state);               // MultipleTimeout
    void ddcHardReset(in long crate, in long channel);       // SingleTimeout
    void ddcHardResetAll(in long crate);                     // MultipleTimeout

    unsigned long ddcGetChannelParameterInt(in long crate, in long channel, in string name);  // SingleTimeout
    float ddcGetChannelParameterFloat(in long crate, in long channel, in string name);        // SingleTimeout
    string ddcGetChannelParameterString(in long crate, in long channel, in string name);      // SingleTimeout

    unsigned long ddcGetCardParameterInt(in long crate, in long card, in string name);  // SingleTimeout
    float ddcGetCardParameterFloat(in long crate, in long card, in string name);        // SingleTimeout
    string ddcGetCardParameterString(in long crate, in long card, in string name);      // SingleTimeout

    unsigned long ddcGetCrateParameterInt(in long crate, in string name);  // SingleTimeout
    float ddcGetCrateParameterFloat(in long crate, in string name);        // SingleTimeout
    string ddcGetCrateParameterString(in long crate, in string name);      // SingleTimeout

    void ddcGetCrateParameters(in long crate, in NameList names, out NameValueList nameValues);   // MultipleTimeout

    // Also set DDC parameters...

    Scan createScan();
    Scan getDefaultScan();

    Trigger createTrigger();
    Trigger getDefaultTrigger();

    ScanList knownScans();
  };

};

---