CalibrationController.idl

Go to the documentation of this file.

//
// ConfigurationController.idl
//
// Created on 20 June 2003, 12:20
// by Matthew Palmer
//
#ifndef IPC_IDL
#include <ipc/ipc.idl> 
#define IPC_IDL
#endif 

#include <SctApi/SctApi.idl>

module Sct_CalibrationController {    

    interface CalibrationController;
    interface ScanRequest;
    interface TestRequest;
    interface SequenceRequest;

    interface ScanLibrary {
        ScanRequest thresholdScan(in unsigned long nTrigs);
        ScanRequest thresholdScanfC(in unsigned long nTrigs, in double calCharge);
        ScanRequest noiseOccupancyScan();
        ScanRequest strobeDelayScan(in unsigned long nTrigs);
        ScanRequest nmaskScan(in unsigned long nTrigs);
        ScanRequest tokenScan();
        ScanRequest rawScan(in unsigned long nTrigs);
        ScanRequest defaultScan();
        //ScanRequest getScan(in string scanName);
        //void addScan(in string scanName, in ScanRequest scan);
    };

    interface TestLibrary {
        TestRequest responseCurve();
        TestRequest threePointGain();
        TestRequest strobeDelay();
        TestRequest noiseOccupancy();
        TestRequest pipeline();
        TestRequest fullBypassBarrel();
        TestRequest fullBypassEndcap();
        TestRequest trimRange();
        TestRequest timeWalk();
        TestRequest nmask();
      TestRequest rxDelay();
      TestRequest rxThreshold();
    };
    
    interface SequenceLibrary {
        SequenceRequest characterizationSequence();        
    };




    interface SequenceRequest {
        string startSequence(in Sct_SctApi::SctApi api);

        TestRequest getNextTest(in unsigned long index);

        void endSequence();
    };



    typedef sequence<double> TestPoints;    

    interface ScanRequest {
      Sct_SctApi::Scan getScan();
      void setScan(in Sct_SctApi::Scan scan);
      boolean configureModules();
      boolean clockByTwo();
      void setClockByTwo(in boolean value);
      boolean isRaw();
      long delay();
      void setWidth(in long value);
      long width();
    };

    interface TestRequest {
        void startTest(in Sct_SctApi::SctApi api, out string name, out unsigned short testVariable, out unsigned long nScans, out TestPoints testPointsData);

        ScanRequest getNextScan(in unsigned long index);

        boolean canFeedback();

        void endTest();
    };


    interface CalibrationController : ipc::freeable {
        const string serverName = "CalibrationControllerServer";
        const string instanceName = "CalibrationControllerImpl";
        
        ScanLibrary getScanLibrary();

        TestLibrary getTestLibrary();

        SequenceLibrary getSequenceLibrary();
        
        oneway void doScan(in ScanRequest s);

        oneway void doTest(in TestRequest t);

        oneway void doSequence(in SequenceRequest r);                


        oneway void abort();
    
        enum UpdateOption {update, noupdate, wait};

        oneway void setUpdateOption(in UpdateOption opt);

        Sct_SctApi::Scan getScan(in unsigned long runNumber, in unsigned long scanNumber); 
      oneway void updateWith(in string testResultInIs);
    };
};

---