configuration.idl

Go to the documentation of this file.

#ifndef IPC_IDL
#include "ipc/ipc.idl"
#define IPC_IDL
#endif

module sctConf {
  struct SlaveConfig {
     string ipramFile;
     string idramFile;
     string extFile;
  };

  typedef sequence <SlaveConfig> SlaveList;

  struct RodConfig {
    unsigned long baseAddress;
//     unsigned long mapSize;
    unsigned long resetLevel;
    SlaveList slaves;

    short validMask;

    octet triggerTypeTTC;
    octet triggerTypeTIM;
    octet offsetBCID;
  };

  struct TimConfig {
    unsigned long baseAddress;
//     unsigned long mapSize;
    unsigned long triggerType;
    float trigFrequency;
    float resetFrequency;

    short validMask;

    octet triggerTypeTTC;
    octet triggerTypeTIM;
    octet offsetBCID;
    unsigned short triggerEnablesInternal;
    unsigned short triggerEnablesTTC;
  };

  // Old direct BOC access
//   struct BOCAddress {
//     long address;
//     long value;           // Possibly byte??
//   };

  struct BOCChannelConfig {
    short current;
    short delay;
    short markSpace;

    short threshold0;
    short delay0;

    short threshold1;
    short delay1;
  };

  struct BOCGlobalConfig {
    short validMask;

    short clockControl;
    short rxDataMode;
    short rxDacClear;
    short txDacClear;
    short vernierFinePhase;
    short vernierClockPhase0;
    short vernierClockPhase1;
    short bpmClockPhase;
    short bregClockPhase;
  };

  //
  // This next section defines an ABCDModule
  // You should refer to RodDaq/Sct/AbcdModule.h for information
  // This structure is defined so that in C/C++ sizeof this structure and sizeof
  // ABCDModule are the same allowing a re-interpret cast.
  //
  

  struct ABCDConfig {
    unsigned long bitField; //This is a bitfield - needs to be interpreted according to Sct/sctStructure.h
  };
  

  typedef octet UnusedArray8_3[3];
  typedef unsigned long UnusedArray32_3[3];
  typedef float RcParam[3];
  struct ABCDCaldata{
    octet rc_function;
    UnusedArray8_3 unused0;
    RcParam rc_params;
    float c_factor;
    UnusedArray32_3 unused1;
  };
  
  typedef unsigned long MaskArray[4];
  struct ABCDBasic {
    ABCDConfig   config;
    octet  vthr;
    octet  vcal;
    octet  delay;
    octet  preamp;
    octet  shaper;
    UnusedArray8_3 unused;
    MaskArray mask;
  };

  typedef octet TrimArray[128];
  struct ABCDChip{
    octet        active;
    octet        address;
    octet        normalMasks;
    octet        target;
    ABCDBasic    basic;
    ABCDCaldata  caldata;
    TrimArray    trim;
  };

  typedef ABCDChip ChipArray[12];
  typedef octet RxArray[2];
  typedef octet UnusedArray8_2[2];
  typedef unsigned long UnusedArray32_7[7];
  typedef octet SerialNumberArray[16];

  struct ABCDModule{
    ChipArray chip;
    octet present;
    octet active;
    octet select;
    octet groupId;
    unsigned long bocConfig;        //Should be ignored
    octet pTTC;
    octet rTTC;
    RxArray rx;
    octet normalMasks;
    octet moduleNumber;
    UnusedArray8_2 unused1;
    SerialNumberArray serialNumber;
    unsigned long mid;
    UnusedArray32_7 unused2;
  };

  
  //
  // End of ABCDModule section
  //


  exception ConfigurationException {
    string detail;
  };

  typedef sequence <unsigned long> PartitionList;
  typedef sequence <unsigned long> CrateList;
  typedef sequence <unsigned long> RodList;
  typedef sequence <unsigned long> MURList;
  typedef sequence <string> ModuleList;
  typedef sequence <string> NameList;
  typedef sequence <octet> CharBlock;

  enum MURType {BARREL, ENDCAP, UNMAPPED, UNKNOWN};

  interface Configuration : ipc::servant {

    const string instanceName = "SCTConfigurationServer";

// Not allowed to throw anything!
//     string getReleaseVersion();
//     string getLocation();

    PartitionList listPartitions()
      raises(ConfigurationException);
    CrateList listCratesInPartition(in unsigned long partition)
      raises(ConfigurationException);
    boolean isDummyCrate(in unsigned long partition, in unsigned long crate);
    RodList listRodsInCrate(in unsigned long partition, in unsigned long crate) 
      raises(ConfigurationException);
    MURList listMURSInRod(in unsigned long partition, in unsigned long crate, in unsigned long rod)
      raises(ConfigurationException);
    ModuleList listModulesInMUR(in unsigned long partition, in unsigned long MUR)
      raises(ConfigurationException);
    ModuleList listRModulesInMUR(in unsigned long partition, in unsigned long MUR)
      raises(ConfigurationException);

    ModuleList listAllModules()
      raises(ConfigurationException);

    ModuleList listUnusedModules()
      raises(ConfigurationException);

    ABCDModule getModuleConfig(in string mod)
      raises(ConfigurationException);

    unsigned short getModuleGroup(in string mod)
      raises(ConfigurationException);
    void setModuleGroup(in string mod, in short group)
      raises(ConfigurationException);

    unsigned long getModuleErrorMask(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                                     in unsigned long channel, in unsigned short link)
      raises(ConfigurationException);
    void setModuleErrorMask(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                            in unsigned long channel, in unsigned short link, in unsigned long mask)
      raises(ConfigurationException);
    void setDefaultModuleErrorMask(in unsigned long mask) 
      raises(ConfigurationException);

    RodConfig getRodConfig(in unsigned long partition, in unsigned long crate, in unsigned long rod)
      raises(ConfigurationException);
    SlaveConfig getDefaultSlaveConfig(in octet type)
      raises(ConfigurationException);
    TimConfig getTimConfig(in unsigned long partition, in unsigned long crate)
      raises(ConfigurationException);

    // These should be unsigned (for comparison with 255)
    CharBlock getFibreMappings(in unsigned long partition, in unsigned long crate, in unsigned long rod)
      raises(ConfigurationException);
    void setFibreMapping(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                         in unsigned long channel, in unsigned long tx, in unsigned long rx0, in unsigned long rx1)
      raises(ConfigurationException);

    BOCChannelConfig getBOCConfig(in unsigned long partition, in unsigned long crate, in unsigned long rod, 
                                  in unsigned long channel)
      raises(ConfigurationException);

    BOCGlobalConfig getBOCGlobalConfig(in unsigned long partition, in unsigned long crate, in unsigned long rod)
      raises(ConfigurationException);

    string printModuleConfig(in ABCDModule conf)
      raises(ConfigurationException);

    MURType getMURType(in unsigned long MUR) 
      raises(ConfigurationException);

    unsigned long getFreeMurId() 
      raises(ConfigurationException);

    void translateToROD(in unsigned long MUR, in unsigned long mod,
                        out unsigned long partition, out unsigned long crate, 
                        out unsigned long rod, out unsigned long channel)
      raises(ConfigurationException);
 
    void translateToRROD(in unsigned long MUR, in unsigned long mod,
                         out unsigned long partition, out unsigned long crate, 
                         out unsigned long rod, out unsigned long channel)
      raises(ConfigurationException);
 
    void translateToSN(in unsigned long MUR, in unsigned long mod,
                       out string sn)
      raises(ConfigurationException);

    void translateToRMUR(in unsigned long RMUR, in unsigned long rmod,
                           out unsigned long MUR, out unsigned long mod)
      raises(ConfigurationException);

    void translateToBarrel(in unsigned long MUR, in unsigned long mod,
                           out unsigned long barrel, out unsigned long row, out long number)
      raises(ConfigurationException);

    void translateToEndcap(in unsigned long MUR, in unsigned long mod,
                           out long disk, out unsigned long ring, out unsigned long number)
      raises(ConfigurationException);

    void translateToPowerSupply(in unsigned long MUR, in unsigned long mod,
                                out unsigned long partition, 
                                out unsigned long crate, out unsigned long channel)
      raises(ConfigurationException);

    void translateFromROD(in unsigned long partition, in unsigned long crate, 
                          in unsigned long rod, in unsigned long channel,
                          out unsigned long MUR, out unsigned long mod)
      raises(ConfigurationException);

    void translateFromRROD(in unsigned long partition, in unsigned long crate, 
                           in unsigned long rod, in unsigned long channel,
                           out unsigned long MUR, out unsigned long mod)
      raises(ConfigurationException);

    void translateFromSN(in string sn,
                         out unsigned long MUR, out unsigned long mod)
      raises(ConfigurationException);

    void translateFromRMUR(in unsigned long MUR, in unsigned long mod,
                           out unsigned long RMUR, out unsigned long rmod)
      raises(ConfigurationException);

    void translateFromBarrel(in unsigned long barrel, in unsigned long row, in long number,
                             out unsigned long MUR, out unsigned long mod)
      raises(ConfigurationException);

    void translateFromEndcap(in long disk, in unsigned long ring, in unsigned long number,
                             out unsigned long MUR, out unsigned long mod)
      raises(ConfigurationException);

    void translateFromPowerSupply(in unsigned long partition, 
                                  in unsigned long crate, in unsigned long channel,
                                  out unsigned long MUR, out unsigned long mod)
      raises(ConfigurationException);


//     void updateModuleConfig(in string mod, in ABCDModule conf)
//       raises(ConfigurationException);

//     void updateRodConfig(in unsigned long partition, in unsigned long crate, in unsigned long rod, in RodConfig conf)
//       raises(ConfigurationException);

    void configureModuleFromStructure(in string number, in ABCDModule mConf)
      raises(ConfigurationException);

    void configureModuleFromFile(in string filename)
      raises(ConfigurationException);

    void configureROD(in unsigned long partition, in unsigned long crate, in unsigned long rod, in RodConfig conf)
      raises(ConfigurationException);

    void configureTIM(in unsigned long partition, in unsigned long crate, in TimConfig conf)
      raises(ConfigurationException);

    void configureBOC(in unsigned long partition, in unsigned long crate, in unsigned long rod, in BOCGlobalConfig conf)
      raises(ConfigurationException);

    void clearAll()
      raises(ConfigurationException);

    void namePartition(in unsigned long partition, in string name)
      raises(ConfigurationException);

    void mapRODMUR(in unsigned long partition, in unsigned long crate, in unsigned long rod, in unsigned long order, 
                   in unsigned long number)
      raises(ConfigurationException);

    void unmapRODMUR(in unsigned long MUR)
      raises(ConfigurationException);

    void mapBarrelMUR(in unsigned long MUR, in unsigned long barrel, in unsigned long row, in long position)
      raises(ConfigurationException);

    void unmapBarrelMUR(in unsigned long MUR)
      raises(ConfigurationException);

    void mapEndcapMUR(in unsigned long MUR, in long disk, in unsigned long quadrant, in unsigned long position)
      raises(ConfigurationException);

    void unmapEndcapMUR(in unsigned long MUR)
      raises(ConfigurationException);

    void mapPowerChannel(in unsigned long MUR, in unsigned long number, 
                         in unsigned long partition, in unsigned long crate, in unsigned long channel)
      raises(ConfigurationException);

    void unmapPowerChannel(in unsigned long MUR, in unsigned long number)
      raises(ConfigurationException);

    void mapModuleMUR(in unsigned long MUR, in unsigned long order, 
                      in unsigned long RMUR, in unsigned long rorder,
                      in string sn)
      raises(ConfigurationException);

    void unmapModuleMUR(in unsigned long MUR, in unsigned long order)
      raises(ConfigurationException);

    void getMapMURROD(in unsigned long MUR, 
                      out unsigned long partition, out unsigned long crate, out unsigned long rod, out unsigned long order)
      raises(ConfigurationException);

    void getMapRODMUR(in unsigned long partition, in unsigned long crate, in unsigned long rod, in unsigned long order, 
                      out unsigned long MUR)
      raises(ConfigurationException);

    MURType getMapMURPhysical(in unsigned long MUR, 
                              out unsigned long plane, out unsigned long section, out unsigned long position)
      raises(ConfigurationException);

    void swapMURNames(in unsigned long MUR1, in unsigned long MUR2) 
      raises(ConfigurationException);

    void modifyDefaultPowerParam(in string state, in string name, in string type, in float value)
      raises(ConfigurationException);

    void modifyHVCardParam(in unsigned long crate, in unsigned long card, 
                           in string name, in string type, in float value)
      raises(ConfigurationException);

    void modifyLVCardParam(in unsigned long crate, in unsigned long card, 
                           in string name, in string type, in float value)
      raises(ConfigurationException);

    void modifyPowerParam(in unsigned long MUR, in unsigned long number, 
                          in string state, in string name, in string type, in float value)
      raises(ConfigurationException);

    void modifyPowerParamCC(in unsigned long crate, in unsigned long channel, 
                            in string state, in string name, in string type, in float value)
      raises(ConfigurationException);

    float getDefaultPowerParam(in string state, in string name, in string type)
      raises(ConfigurationException);

    float getHVCardParam(in unsigned long crate, in unsigned long card, in string name, in string type)
      raises(ConfigurationException);

    float getLVCardParam(in unsigned long crate, in unsigned long card, in string name, in string type)
      raises(ConfigurationException);

    float getPowerParam(in unsigned long MUR, in unsigned long number, in string state, in string name, in string type)
      raises(ConfigurationException);

    float getPowerParamCC(in unsigned long crate, in unsigned long channel, in string state, in string name, in string type)
      raises(ConfigurationException);

    NameList listDefaultPowerParams()
      raises(ConfigurationException);

    NameList listDCSChannelParams()
      raises(ConfigurationException);

    NameList listDCSCardParams()
      raises(ConfigurationException);

    NameList listDCSCrateParams()
      raises(ConfigurationException);

    void configureBOCChannel(in unsigned long MUR, in unsigned long position, in BOCChannelConfig conf)
      raises(ConfigurationException);

    void useMRSForMessages(in boolean valid)
      raises(ConfigurationException);

    void useISForChanges(in boolean valid)
      raises(ConfigurationException);

    void loadConfiguration(in string filename)
      raises(ConfigurationException);

    string getConfigurationFileName()
      raises(ConfigurationException);

    void saveConfiguration(in string filename)
      raises(ConfigurationException);

    void saveModuleConfiguration(in string sn, in string filename)
      raises(ConfigurationException);

    string getModuleConfigurationString(in string modsn, in ABCDModule config)
      raises(ConfigurationException);

    void writePowerSupplyConfiguration(in string directory)
      raises(ConfigurationException);

  };

  typedef sequence <unsigned long> RunNumberList;

  interface ConfigurationArchive : ipc::servant {
    const string instanceName = "Configuration_Archive_Server";

    Configuration getOldRunConfiguration(in unsigned long runNumber, in boolean start);

    RunNumberList listConfigurationRuns();
  };
};

---